Injecting dependencies into a TransferObject

This is a step-by-step example on how to setup Coldspring and Transfer to inject dependencies into your Transfer decorators. Normally Coldspring can only help with defined beans rather than ones you get via transfer.get() or transfer.new(). Mark added a bridge that lets them work together but I found his example too brief to understand. With his help, I have it working in my MG/CS/Transfer app. It’s easier than it seems.

Updated 1/11/08 – based on input from Sean Corfield, I’ve revised the setter method to behave more like ColdSpring and eliminate the case/switch statement.

Read on:

The goal

I’m going to use an example from my application today, where I want to make an AttendeeService available in my member bean (decorator) so that I can ask the member to give me its registration history. I want the bean to be smarter. Currently I do:

attendeeService.getRegistrationsByMember(member)

And I want to do:

member.getRegistrations();

So we have attendeeService.cfc, member.cfc, and coldspring.xml. We are going to add one new file, called injectorObserver.cfc to the mix, add a few new methods to the bean/decorator, do a little coldspring configuration and we’ll be good.

The Code

Here’s the relevant code from each file. First, we create the ability to set/get the attendee service on my member bean. So add these two methods to member.cfc:

<cffunction name="setAttendeeService" access="public" returntype="void" output="false">
	<cfargument name="AttendeeService" type="any" required="true">
	<cfset variables.AttendeeService = arguments.AttendeeService />
</cffunction>
<cffunction name="getAttendeeService" access="public" returntype="any" output="false">
	<cfreturn variables.AttendeeService />
</cffunction>

Pretty standard for Coldspring. Now, create a new file called injectorObserver.cfc. This filename is totally arbitrary as is its location. We are creating an object that will monitor when a new TransferObject is created and dynamically inject the services we desire into it on the fly.

Note: Transfer decorators can have an optional configure() method that is run right after they are created. These injected services are added immediately after configure() and are not available during configure().

injectorObserver.cfc:

<cfcomponent displayname="injectorObserver" hint="Used to inject service dependencies into transfer decorator objects" output="false">

<cffunction name="init" access="public" output="false" returntype="any">
	<cfargument name="transfer" type="transfer.com.Transfer" required="true" />

	<cfset var serviceName = "" />
	<cfset variables.services = structNew() />

	
	<cfloop item="serviceName" collection="#arguments#">
		<cfset variables.services[serviceName] = arguments[serviceName] />
	</cfloop>

	<cfset arguments.transfer.addAfterNewObserver(this) />
</cffunction>

<cffunction name="actionAfterNewTransferEvent" hint="Do something on the new object" access="public" returntype="void" output="false">
    <cfargument name="event" hint="" type="transfer.com.events.TransferEvent" required="Yes">

    <cfset var obj = arguments.event.getTransferObject() />
    <cfset var serviceName = "" />

	
	<cfloop item="serviceName" collection="#variables.services#">
		<cfif structKeyExists(obj, "set#serviceName#")>
			<cfinvoke component="#obj#" method="set#serviceName#">
				<cfinvokeargument name="#serviceName#" value="#variables.services[serviceName]#" />
			</cfinvoke>
		</cfif>
	</cfloop>

</cffunction>

</cfcomponent>

The name of the method, actionAfterNewTransferEvent, is fixed. That’s what Transfer looks for. The method looks at the decorator-to-be and searches for any methods that match the set[InjectedObject]() naming scheme.

Coldspring Config

Now this injectorObserver must exist if it’s going to do anything for us. So we have to tell Coldspring to create it on load. Add this to your coldspring.xml:

<bean id="injectorObserver" class="path.to.injectorObserver" lazy-init="false">
	<constructor-arg name="transfer"><bean id="transfer" factory-bean="transfer" factory-method="getTransfer" /></constructor-arg>
	<constructor-arg name="attendeeService"><ref bean="attendeeService" /></constructor-arg>
</bean>

Because Coldspring creates beans on demand, we need to force it to instantiate injectorObserver so it’s available to watch for decorators that need injecting. The lazy-init tells Coldspring to create the bean on startup and the init() method adds itself as an observer. From that point on, injectorObserver will be listening to Transfer for any created beans.

Test it!

You’re ready to go. Now just get the member bean:

<cfset member = transfer.get("member.member", 1) />
<cfdump var="#member.getAttendeeService()#" />

And this shows me the methods of my AttendeeService. Now you can inject your service layer into your beans!

If you want to inject more services, just create more set/get pairs in the decorator and tell Coldspring to pass them to injectorObserver’s init(). The bean will automatically pick it up.

Update 1/2009 – I finally switched from my homebrewed code to Brian Kotek’s BeanInjector and TDOBeanInjector from his coldspringutils project on RIAForge and both are working great.